Apex Archives - Cloudy With a Chance of Code

A problem was posed recently for another developer in the forcedotcom community where he was running out of http callouts while trying to use a REST API service. I figured this is the perfect reason to take a break and post a new blog post.

One solution I’ve used in the past to get around issues like this when working in VisualForce is to chain actions together. This solution uses actionFunction with names that are set in the controller. If after the rerender the string is not null the oncomplete javascript will kick off the next action in turn giving another 10 callouts if necessary. I tend to use this solution frequently with slight modifications between booleans to call the same action.

One example of this is calling a web service that has a timeout set. You can chain the action to a boolean in the oncomplete which will start the action again until you stop it with the boolean, usually after 3 or so tries.

I’m still a newbie to WordPress so I’m getting used to the code highlighting plugins. SyntaxHighlighter takes issue with my xml have self closing tags, so just know the actionfunctions and commandbutton don’t require a specific closing tag like that, it can use the standard /> closing tag. This doesn’t apply anymore, code highlighting was fixed finally

ChainedActionController.cls

public class ChainedActionController {
    public ChainedActionController() { }
    
    private Integer chainMax = 5;
    private Integer chainCount = 0;
    
    
    public String outputText {
        get {
            if(outputText == null) outputText = '';
            return outputText;
        }
        set;
    }
    
    public String chainedActionFunction {
        get {
            if(chainedActionFunction == null) chainedActionFunction = '';
            return chainedActionFunction;
        }
        set;
    }
    
    public void actionOne() {
        this.outputText = 'actionOne set this text';
        
        // set the next chain if we haven't exceeded the defined max count
        if(chainCount++ < chainMax) {
            this.chainedActionFunction = 'actionTwo';
        } else { 
            this.chainedActionFunction = '';
        }
    }
    
    public void actionTwo() {    
        this.outputText = 'actionTwo set this text';
        
        // this could also be done with booleans depending on your use case
        if(chainCount++ < chainMax) {
            this.chainedActionFunction = 'actionOne';
        } else { 
            this.chainedActionFunction = '';
        }
    }
    
}

ChainedActionExample.page

<apex:page controller="ChainedActionController">
    <apex:form id="inputForm">
        <div style="border: 1px solid #777; background-color: #efefef; color: #444; padding: 5px;">
             output: {!outputText}
        </div>        
        <br/><br/>
        Status:
        <apex:actionStatus id="actOne">
            <apex:facet name="start">
                Action one is running!
            </apex:facet>
        </apex:actionStatus>
        <apex:actionStatus id="actTwo">
            <apex:facet name="start">
                Action one is running!
            </apex:facet>
        </apex:actionStatus>
        <br/><br/>
        <apex:actionFunction status="actOne" name="actionOne" action="{!actionOne}" rerender="inputForm" oncomplete="if('{!chainedActionFunction}' != '') eval('{!chainedActionFunction}();')" />
        <apex:actionFunction status="actTwo" name="actionTwo" action="{!actionTwo}" rerender="inputForm" oncomplete="if({!chainedActionFunction}) eval('{!chainedActionFunction}();')"/>
        <apex:commandButton status="actOne" action="{!actionOne}" rerender="inputForm" oncomplete="if({!chainedActionFunction}) eval('{!chainedActionFunction}();')" value="Start"/>
    </apex:form>
</apex:page>

Recently I had to find a way to convert strings into their ascii decimal value. I solved this by converting to hex first, and then using some simple math to get the decimal value of each character. This won’t work on double byte characters, but that wasn’t my use case so for now this will work for me.

Edit: After some thinking, making this double byte or even multiple byte wouldn’t be too hard if you were to figure out the ratio of input length to hex output length, then increase the formula to increase the power of 16. I’ll try to get back to this later this week and update for those using multi byte characters.

Edit2: After more investigation and learning the ins and outs of UTF8 I now fully understand the return values of the EncodingUtil.convertToHex method. It returns bytes in UTF8 format. Each byte explains how many bytes that character uses. Some bytes use 1 (old school ascii compatible 0-127), some use 2, 3 or even 4. The range in the first byte tells a story about that character. I have a method to convert these to decimals that can be parsed by String.fromCharArray if anyone is interested. So since each byte is encoded in this, this technically handles UTF8 just fine, and works perfect for my apex ported AES encryption

private static Map<String,Integer> hexMap = new Map<String,Integer>();
static {
	hexMap.put('0',0);
	hexMap.put('1',1);
	hexMap.put('2',2);
	hexMap.put('3',3);
	hexMap.put('4',4);
	hexMap.put('5',5);
	hexMap.put('6',6);
	hexMap.put('7',7);
	hexMap.put('8',8);
	hexMap.put('9',9);
	hexMap.put('A',10);
	hexMap.put('B',11);
	hexMap.put('C',12);
	hexMap.put('D',13);
	hexMap.put('E',14);
	hexMap.put('F',15);
	hexMap.put('a',10);
	hexMap.put('b',11);
	hexMap.put('c',12);
	hexMap.put('d',13);
	hexMap.put('e',14);
	hexMap.put('f',15);
}

public static List<Integer> stringToInt(String input) {
	String hex = EncodingUtil.convertToHex(Blob.valueOf(input));
	List<Integer> retValues = new List<Integer>();

	for(Integer i=0;i<hex.length();i+=2) {
		retValues.add( (hexMap.get(hex.substring(i,i+1))*16) + (hexMap.get(hex.substring(i+1,i+2))) );
	}
	return retValues;
}

Apex

Chaining executions with actionFunction

Converting string to decimal character array in Apex